システムトレードブログ

株の自動売買ツールを作る(13)

トレシズ自動売買の開発方法

ここ最近完全にUWSC研究室のようなブログになってしまい申し訳ないです苦笑

そろそろ普通のシストレ記事も書かせていただきますね笑

今日は自動発注のソースをIFD注文に対応させました。

これはゴッドブレス2を自動売買化するために必須の作業だったため個人的にも結構本気で作ってみましたが、

プログラムがどんどん長くなり意味不明になってきていますね苦笑

ただこれはかなり便利でして、

仕掛け+損切りという注文を、コマンド一発で発注できるという優れものです。

スリッページ関連でライブスターを避ける方もいらっしゃるのではないかと思いますが、

個人的には売買手数料の安さとこのIFD注文、OCO注文にこそライブスターの良さがあると思っていたりします笑

たとえばですが、IFD注文が使えない証券会社ですと、

極端な例ではありますが、全銘柄がストップ安直行といった最悪の地合の場合、

仕掛けたのはいいものの全銘柄がストップ安に到達することになります。

ここでIFD注文を使って逆指値の損切りも同時に入れておきますと、

場を見ていなくてもある程度は損失が抑えられる可能性が高い、とは言えるかもしれませんね〜。

スリッページをとるか、それともこういった運用の簡単さ+リスク管理面をとるかという究極の選択になってくる感はありますが、

私個人はスリッページの大きさはあまり気にしないタイプなので(ぇ、

こういった「運用時のラクさ」を重視する感じなのかもしれません苦笑

GMOクリックとライブスターは、両方ともおすすめだと思っています笑

■更新箇所
・IFD注文に対応
・非取扱銘柄のエラー処理を追加

■UWSC側(Dドライブ直下に「UWSC」フォルダを作り、その中にEXE化したorder.exeを保存)
----------------------------------------------------
Public LOGINURL = "https://lv01.live-sec.co.jp/webbroker3/44/i/WEB3Index.jsp?aa_odrdv=2" // ライブスターログインURL
Public LOGFILE = "./log.txt" // ログファイルへのパス
Public CONFIGFILE = "./config.txt" // 設定ファイルへのパス
Public IE = 0 // IEオブジェクト用
Public SLEEPTIME // 画面遷移時の休止時間
Public CHANGESG // 信用建禁止銘柄の場合現物で発注する場合:1 しない場合
Public TEST // テストの場合1 実際に発注する場合0

// 設定ファイル読み込み
fid = FOPEN(CONFIGFILE,F_READ)
SLEEPTIME = getNumber(FGET(fid, 1))*0.1
CHANGESG = getNumber(FGET(fid, 2))
TEST = getNumber(FGET(fid, 3))
FCLOSE(fid)

//PARAM_STR[0]: 証券会社 ライブスターLS
//PARAM_STR[1]: ログインID
//PARAM_STR[2]: ログインパスワード
//PARAM_STR[3]: 取引パスワード
//PARAM_STR[4]: 制度信用S 現物G
//PARAM_STR[5]: 買いL 売りS
//PARAM_STR[6]: 銘柄コード
//PARAM_STR[7]: 銘柄名
//PARAM_STR[8]: 成行N 引成H 指値S 寄指Y 引指I 不成F 逆指値G 逆指値(指値指定)J
//PARAM_STR[9]: 株数
//PARAM_STR[10]: 指値
//PARAM_STR[11]: 逆指値
//PARAM_STR[12]: 注文ID
//PARAM_STR[13]: OCO/IFD
//PARAM_STR[14]: IFD:指値
//PARAM_STR[15]: IFD:逆指値
//PARAM_STR[16]: IFD:執行条件 成行N 指値S 寄指Y 引指I 不成F 逆指値G 逆指値(指値指定)J

// IEのウィンドウが開いているかどうかチェック
flg = 0
Obj_Shell = CreateOleObj("Shell.Application")
for i = 0 to Obj_Shell.Windows.Count - 1
Obj = Obj_Shell.Windows.Item(i)
Try
ifB Obj > 0 and pos("iexplore.exe", Obj.Fullname) > 0
IE = Obj
IE.visible = True
flg = flg + 1
BREAK
Endif
Except

EndTry
NEXT

// IEのウィンドウが開いていない場合
ifB flg = 0

// ログイン処理へ
login(PARAM_STR[1], PARAM_STR[2], PARAM_STR[3], PARAM_STR[4], PARAM_STR[5], PARAM_STR[6], PARAM_STR[7], PARAM_STR[8], PARAM_STR[9], PARAM_STR[10], PARAM_STR[11], PARAM_STR[12], PARAM_STR[13], PARAM_STR[14], PARAM_STR[15], PARAM_STR[16])

// IEのウィンドウが開いている場合はメインメニューにいるかどうか調べる
else
// メインメニューにいるかどうか調べる
ifB pos("メインメニュー",IE.document.body.innerText)
// ログイン中は何もしない
else
// ウィンドウを閉じてからログイン処理へ
IE.quit
login(PARAM_STR[1], PARAM_STR[2], PARAM_STR[3], PARAM_STR[4], PARAM_STR[5], PARAM_STR[6], PARAM_STR[7], PARAM_STR[8], PARAM_STR[9], PARAM_STR[10], PARAM_STR[11], PARAM_STR[12], PARAM_STR[13], PARAM_STR[14], PARAM_STR[15], PARAM_STR[16])
Endif
Endif

order(PARAM_STR[1], PARAM_STR[2], PARAM_STR[3], PARAM_STR[4], PARAM_STR[5], PARAM_STR[6], PARAM_STR[7], PARAM_STR[8], PARAM_STR[9], PARAM_STR[10], PARAM_STR[11], PARAM_STR[12], PARAM_STR[13], PARAM_STR[14], PARAM_STR[15], PARAM_STR[16])

//■数字を取得
Function getNumber(str)
Dim regex = CREATEOLEOBJ("VBScript.RegExp")
WITH regex
.Pattern = "\D" // 数字以外の文字に一致
.Global = TRUE // 全部が対象
str2 = .Replace(str, "") // 一致した文字を""に置き換える
ENDWITH
Result = str2
Fend

//■日付取得
Function getDateStr()
GETTIME()
Result = G_TIME_YY4 + "/" + G_TIME_MM2 + "/" + G_TIME_DD2 + " " + G_TIME_HH2 + ":" + G_TIME_NN2 + ":" + G_TIME_SS2
Fend

//■指値文字列取得
Function getSashineStr(ls, how, sashine)
Dim sashineStr = ""
ifB how = "N" OR how = "H" OR how = "G"
sashineStr = ""
else
sashineStr = sashine + "円"
Endif
Result = sashineStr
Fend

//■逆指値文字列取得
Function getSashineGStr(ls, how, sashineG, child=0)
Dim sashineGStr = ""
ifB how = "G" OR how = "J"
ifB ls = "S" // 信用売り(逆指値)
sashineGStr = sashineG + "円"
ifB child = 1
sashineGStr = sashineGStr + "以上"
else
sashineGStr = sashineGStr + "以下"
Endif
else // 買い(逆指値)
sashineGStr = sashineG + "円"
ifB child = 1
sashineGStr = sashineGStr + "以下"
else
sashineGStr = sashineGStr + "以上"
Endif
Endif
else
sashineGStr = ""
Endif
Result = sashineGStr
Fend

//■スリープ
Procedure ieSleep(IE)
REPEAT
SLEEP(SLEEPTIME)
UNTIL !IE.busy AND IE.readystate=4
Fend

//■エラー時の処理
Procedure error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, ok, msg, oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)

Dim fid = FOPEN(LOGFILE, F_READ or F_WRITE)
FPUT(fid, getDateStr() + "," + sgStr + "," + lgStr + "," + mCode + "," + mName + "," + howStr + "," + kabusu + "株" + "," + getSashineStr(ls, how, sashine) + "," + getSashineGStr(ls, how, sashineG) + "," + ocoifd + "," + c_howStr + "," + getSashineStr(ls, c_how, c_sashine) + "," + getSashineGStr(ls, c_how, c_sashineG, 1) + "," + ok + "," + msg + "," + oid)
FCLOSE(fid)

IESETDATA(IE,True,"","7.戻る")
ieSleep(IE)

IELINK(IE,"メインメニューへ")
ieSleep(IE)

EXITEXIT
Fend

//■信用→現物変更時の処理
Procedure orderChange(sgStr, lgStr, howStr, loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, ok, msg, oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)

Dim fid = FOPEN(LOGFILE, F_READ or F_WRITE)
FPUT(fid, getDateStr() + "," + sgStr + "," + lgStr + "," + mCode + "," + mName + "," + howStr + "," + kabusu + "株" + "," + getSashineStr(ls, how, sashine) + "," + getSashineGStr(ls, how, sashineG) + "," + ocoifd + "," + c_howStr + "," + getSashineStr(ls, c_how, c_sashine) + "," + getSashineGStr(ls, c_how, c_sashineG, 1) + "," + ok + "," + msg + "," + oid)
FCLOSE(fid)

IESETDATA(IE,True,"","7.戻る")
ieSleep(IE)

IELINK(IE,"メインメニューへ")
ieSleep(IE)

order(loginId, loginPw, orderPw, "G", ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
Fend

//■発注時の処理
Procedure complete(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, ok, msg, oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)

Dim fid = FOPEN(LOGFILE, F_READ or F_WRITE)
FPUT(fid, getDateStr() + "," + sgStr + "," + lgStr + "," + mCode + "," + mName + "," + howStr + "," + kabusu + "株" + "," + getSashineStr(ls, how, sashine) + "," + getSashineGStr(ls, how, sashineG) + "," + ocoifd + "," + c_howStr + "," + getSashineStr(ls, c_how, c_sashine) + "," + getSashineGStr(ls, c_how, c_sashineG, 1) + "," + ok + "," + msg + "," + oid)
FCLOSE(fid)

IELINK(IE,"メインメニューへ")
ieSleep(IE)

EXITEXIT
Fend

//■ログイン
Procedure login(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)

sgStr = "現物" // 現物or信用
lgStr = "買い" // 買いor売り
howStr = "成行" // 仕掛け方法

ifB sg = "S"
sgStr = "信用" // 信用
ifB ls = "S" // 信用売り
lgStr = "売り" // 売り
Endif
Endif

IE = CREATEOLEOBJ("InternetExplorer.Application")
IE.visible = True
IE.navigate(LOGINURL)
ieSleep(IE)

IESETDATA(IE,loginId,"aa_accd")
IESETDATA(IE,loginPw,"lg_pw")
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

// 該当銘柄が存在しない場合
ifB pos("必須入力です",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "ログインID/パスワード未入力", oid, ocoifd, c_sashine, c_sashineG, c_how, "")
elseif pos("正しくありません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "ログインID/パスワードエラー", oid, ocoifd, c_sashine, c_sashineG, c_how, "")
elseif pos("エラーが発生",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "ログインロック", oid, ocoifd, c_sashine, c_sashineG, c_how, "")
Endif

IELINK(IE,"メインメニューへ")
ieSleep(IE)
Fend

//■発注
Procedure order(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)

sgStr = "現物" // 現物or信用
lgStr = "買い" // 買いor売り
howStr = "成行" // 仕掛け方法
pdcd = "eq_pdcd" // 銘柄検索
ttp_x = "eq_ttp_x" // 特定口座
odqt = "eq_odqt" // 株数
ectpodpdiv_x = "eq_ectpodpdiv_x" // 注文方法
lpr = "eq_lpr" // 指値
sodcpr = "eq_sodcpr" // 逆指値
ectpodpdiv_x = "eq_ectpodpdiv_x" // 逆指値の執行条件
edttp_x = "eq_edttp_x" // 当日限り
odctp_x = "eq_ifdodc_x" // IFD注文の注文種類
c_howStr = "成行" // IFD注文の手仕舞い方法
ifdorcete = "eq_ifdorcete" // IFD注文の注文種類(子)
ifdlp = "eq_ifdlp" // 指値(子)
ifdsporcepe = "eq_ifdsocp" // 逆指値(子)
ifdeccdteorpediv = "eq_ifdectopdv" // 執行条件(子)

ifB sg = "S"

sgStr = "信用" // 信用
pdcd = "mr_pdcd" // 銘柄検索(信用)
ttp_x = "mr_ttp_x" // 特定口座(信用)
odqt = "mr_odqt" // 株数(信用)
ectpodpdiv_x = "mr_ectpodpdiv_x" // 注文方法(信用)
lpr = "mr_lpr" // 指値(信用)
sodcpr = "mr_sodcpr" // 逆指値(信用)
ectpodpdiv_x = "mr_ectpodpdiv_x" // 逆指値の執行条件(信用)
edttp_x = "mr_edttp_x" // 当日限り(信用)
odctp_x = "mr_odctp_x" // IFD注文の注文種類
ifdorcete = "mr_ifdorcete" // IFD注文の注文種類(子)
ifdlp = "mr_ifdlp" // 指値(子)
ifdsporcepe = "mr_ifdsporcepe" // 逆指値(子)
ifdeccdteorpediv = "mr_ifdeccdteorpediv" // 執行条件(子)

ifB ls = "S" // 信用売り

lgStr = "売り" // 売り

// 信用取引をクリック
IELINK(IE,"信用取引")
ieSleep(IE)

// セッションが切れた場合
ifB pos("ログアウトされました",IE.document.body.innerText)
IE.quit
login(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
order(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
Endif

// 新規売をクリック
IELINK(IE,"新規売")
ieSleep(IE)

else // 信用買い

// 信用取引をクリック
IELINK(IE,"信用取引")
ieSleep(IE)

// セッションが切れた場合
ifB pos("ログアウトされました",IE.document.body.innerText)
IE.quit
login(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
order(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
Endif

// 新規買をクリック
IELINK(IE,"新規買")
ieSleep(IE)
Endif

else // 現物買い

// 株式現物をクリック
IELINK(IE,"株式現物")
ieSleep(IE)

// セッションが切れた場合
ifB pos("ログアウトされました",IE.document.body.innerText)
IE.quit
login(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
order(loginId, loginPw, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, oid, ocoifd, c_sashine, c_sashineG, c_how)
Endif

// 買付をクリック
IELINK(IE,"買付")
ieSleep(IE)
Endif

// 銘柄検索
IESETDATA(IE,mCode,pdcd)
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

// 該当銘柄が存在しない場合
ifB pos("優先市場が設定されていません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "該当銘柄なし", oid, ocoifd, c_sashine, c_sashineG, c_how, "")
elseif pos("お取扱しておりません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "非取扱銘柄", oid, ocoifd, c_sashine, c_sashineG, c_how, "")
Endif

ifB ocoifd = "IFD" // IFD
ifB how = "G" OR how = "J" // 逆指値
howStr = "逆指値"
else
howStr = "通常"
Endif
IESETDATA(IE,"IFD注文","jsp_cond_chg")
IESETDATA(IE,True,"","4.画面切替")
ieSleep(IE)
elseif how = "G" OR how = "J" // 逆指値
howStr = "逆指値"
IESETDATA(IE,"逆指値S","jsp_cond_chg")
IESETDATA(IE,True,"","4.画面切替")
ieSleep(IE)
IESETDATA(IE,sashineG,sodcpr)
Endif

// 特定口座
IESETDATA(IE,1,ttp_x,"1")

// 株数
IESETDATA(IE,kabusu,odqt)

// IFD注文の場合のみ
ifB ocoifd = "IFD"
ifB how = "G" OR how = "J" // 逆指値
IESETDATA(IE,"逆指値S",odctp_x)
IESETDATA(IE,sashineG,sodcpr)
Endif
Endif

ifB how = "H" // 引成
howStr = "引成"
IESETDATA(IE,"引成",ectpodpdiv_x)
elseif how = "S" // 指値
howStr = "指値"
IESETDATA(IE,"指値",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "Y" // 寄指
howStr = "寄指"
IESETDATA(IE,"寄指",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "I" // 引指
howStr = "引指"
IESETDATA(IE,"引指",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "F" // 不成
howStr = "不成"
IESETDATA(IE,"不成",ectpodpdiv_x)
IESETDATA(IE,sashine,lpr)
elseif how = "J" // 逆指値(指値指定)
howStr = "逆指値(指値指定)"
IESETDATA(IE,sashine,lpr)
IESETDATA(IE,"指値",ectpodpdiv_x)
Endif

// IFD注文の場合のみ子注文を設定
ifB ocoifd = "IFD"
ifB c_how = "G" OR c_how = "J" // 逆指値
IESETDATA(IE,"逆指値S",ifdorcete)
IESETDATA(IE,c_sashineG,ifdsporcepe)
Endif

ifB c_how = "S" // 指値
c_howStr = "指値"
IESETDATA(IE,"指値",ifdeccdteorpediv)
IESETDATA(IE,c_sashine,ifdlp)
elseif c_how = "Y" // 寄指
c_howStr = "寄指"
IESETDATA(IE,"寄指",ifdeccdteorpediv)
IESETDATA(IE,c_sashine,ifdlp)
elseif c_how = "I" // 引指
c_howStr = "引指"
IESETDATA(IE,"引指",ifdeccdteorpediv)
IESETDATA(IE,c_sashine,ifdlp)
elseif c_how = "F" // 不成
c_howStr = "不成"
IESETDATA(IE,"不成",ifdeccdteorpediv)
IESETDATA(IE,c_sashine,ifdlp)
elseif c_how = "J" // 逆指値(指値指定)
c_howStr = "逆指値(指値指定)"
IESETDATA(IE,"指値",ifdeccdteorpediv)
IESETDATA(IE,c_sashine,ifdlp)
Endif
Endif

// 当日限り
IESETDATA(IE,1,edttp_x,"1")

// 発注確認
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

// エラーチェック
ifB pos("バッチ処理中",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "注文時間外", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
elseif pos("正しくありません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "売買単位エラー", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
elseif pos("不足しています",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "余力不足", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
elseif pos("超えています",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "値幅制限エラー", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
elseif pos("抵触",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "アップティックルール規制", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
elseif pos("受付時間外",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "受付時間外", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
elseif pos("制限されています",IE.document.body.innerText)
ifB sg = "S" AND ls = "L" AND CHANGESG = 1 // 現物で発注
orderChange(sgStr, lgStr, howStr, loginId, loginPw, orderPw, "G", ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用規制銘柄", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
else
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用規制銘柄", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
Endif
elseif pos("できません",IE.document.body.innerText)
ifB sg = "S" AND ls = "L" AND CHANGESG = 1 // 現物で発注
orderChange(sgStr, lgStr, howStr, loginId, loginPw, orderPw, "G", ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用不可", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
else
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "信用不可", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
Endif
Endif

// 発注
IESETDATA(IE,orderPw,"aa_pw")

ifB TEST = 0 // 実際に発注する場合
IESETDATA(IE,True,"","1.実行")
ieSleep(IE)

ifB pos("正しくありません",IE.document.body.innerText)
error(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "×", "取引パスワードエラー", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
Endif

complete(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "○", "発注完了", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
else // テストの場合
complete(sgStr, lgStr, howStr, orderPw, sg, ls, mCode, mName, how, kabusu, sashine, sashineG, "○", "発注完了(テスト)", oid, ocoifd, c_sashine, c_sashineG, c_how, c_howStr)
Endif

Fend
----------------------------------------------------

■設定ファイル(Dドライブ直下に「UWSC」フォルダを作り、その中にconfig.txtという名前で保存)
----------------------------------------------------
SLEEPTIME = 1 // 画面遷移時の休止時間
CHANGESG = 1 // 信用建禁止銘柄を現物で発注する場合1 しない場合0(半角)
TEST = 1 // テストの場合1 実際に発注する場合0(半角)
----------------------------------------------------

■コマンドプロンプト側
・通常注文の場合
----------------------------------------------------
"D:\UWSC\order.exe" "LS" "証券会社ログインID" "証券会社ログインパスワード" "証券会社取引パスワード" "G" "L" "4755" "楽天" "G" "100" "1101" "1102" "12345"
----------------------------------------------------

・IFD注文の場合(1102円以上になったら逆指値で成行買い、1100円以下になったら逆指値で成行売り)
----------------------------------------------------
"D:\UWSC\order.exe" "LS" "証券会社ログインID" "証券会社ログインパスワード" "証券会社取引パスワード" "G" "L" "4755" "楽天" "G" "100" "1102" "1102" "12345" "IFD" "1100" "1100" "G"
----------------------------------------------------

トレシズの「自動売買の開発方法」の記事

前々記事:UWSCでイザナミを自動的に操作する(3)
前の記事:UWSCでイザナミを自動的に操作する(4)
今の記事:株の自動売買ツールを作る(13)
次の記事:株の自動売買ツールを作る(14)
次々記事:UWSCでイザナミを自動的に操作する(5)

おすすめ記事

株の自動売買ツールを作る(4)

さて、昨日の続きです。今日はあまり進んでいませんが苦笑まず、「自動売買に適した…

イザナミ+リアルタイム株価対応戦略を作る(4)

さっきからプログラムを作成しておりましたが、…意外とあっさり完成してしまいました…

> このページのURLをPCメールアドレスに送る